某廢柴的廢棄日記

Pingback 回去 XD

由於最近收圖有點胸兇，總是讓PNG優化工序超時完成，只好靠 Multi-threading 加快一下進度了。
和 scribe 的不同，我比較想用 batch 加外部工具達成，當然就是 *nix 眾都熟悉的 xargs 。

xargs 在 Windows 下有幾個版本： cygwin xargs、MSYS xargs、UnxUtils xargs、GnuWin32 xargs。
但是我試到最後，只有 cygwin xargs 的支援比較全面。

比 scribe 的我還增加了 "/b" 參數讓優化過程在標準以下的優先度下執行，不會讓你受打擾 XD

pngoutall_nproc.bat:

@echo off

SET PNGOPFX=%~dp0
SET CYGPFX=D:\cygwin\bin\

if NOT "%1"=="/r" GOTO pre2
SHIFT
SET DIRSW=/s

:pre2
if NOT "%1"=="/b" GOTO proc
SHIFT
SET POOSW=/b

:proc
dir /b %DIRSW% *.png | %CYGPFX%xargs.exe -d '\n' --max-args=1 -P %NUMBER_OF_PROCESSORS% %PNGOPFX%pngoptone.bat %POOSW%

SET DIRSW=
SET POOSW=
SET PNGOPFX=
SET CYGPFX=

pngoptone.bat:

@echo off

SET POOPFX=%~dp0

if NOT "%1"=="/b" GOTO PROC
SHIFT
SET EXECPFX=start /b /wait /belownormal

:PROC
 %POOPFX%binmay.exe -i "%~1" -o nul -s "00 00 00 08 61 63 54 4c" 2> nul
 if ERRORLEVEL 1 (
  %POOPFX%touch.exe -r "%~1" "%~1.time"
  %EXECPFX% %POOPFX%optipng.exe -zw32k -zc9 -zm9 -zs0,3 -f0,5 -i0 "%~1"
  if not ERRORLEVEL 1 (
   %EXECPFX% %POOPFX%advdef.exe -z -4 "%~1"
   %EXECPFX% %POOPFX%deflopt.exe -b "%~1"
   %EXECPFX% %POOPFX%pngout /y /b0 "%~1"
   if not ERRORLEVEL 2 (
    %EXECPFX% %POOPFX%advdef.exe -z -4 "%~1"
    %EXECPFX% %POOPFX%deflopt.exe -b "%~1"
   )
  )
  %POOPFX%touch.exe -r "%~1.time" "%~1"
  if exist "%~1.time" del "%~1.time"
 ) else (
  ren "%~1" "%~n1.apng"
 )

SET EXECPFX=
SET POOPFX=

backlink: 用 Python 跑 Multi-threading 版 PNG 最佳化

標籤： Software